finish
/clear

/title, Simple Conduction Example
/PREP7				! Enter preprocessor

! define geometry

length=1.0
height=1.0
blc4,0,0,length, height		! area - one corner, then width and height

! mesh 2D areas

ET,1, PLANE55			! Thermal element only
MP,Dens,1,920			! Density
mp,c,1,2.040			! Specific heat capacity
mp,kxx,1,5			! Thermal conductivity
ESIZE,0.05			! Element size
AMESH,ALL			! Mesh area

FINISH
/SOLU

ANTYPE,4			! Transient analysis

time,300			! Time at end = 300

nropt,full			! Newton Raphson = full
lumpm,0				! Lumped mass approx off
nsubst,20			! 20 substeps
neqit,100			! Max no. of iterations = 100
autots,off			! Auto time search on
lnsrch,on			! Line search on
outres,all,all			! Output data for all substeps
kbc,1

! fixed temp BC's
NSEL,S,LOC,Y,height		! select nodes on top with y=height
D,ALL,TEMP,500			! apply fixed temp of 500K
NSEL,ALL
NSEL,s,LOC,Y,0
D,ALL,TEMP,100			! apply fixed temp of 100K
NSEL,ALL
IC,all,Temp,100			! Initial Conditions: 100K

SOLVE
FINISH

/POST1				! Enter postprocessor
/CONT,1,8,100,,500		! Define a contour range
PLNSOL,TEMP			! Plot temperature contour
ANTIME,20,0.5,,0,2,0,500	! Animate temp over time